home *** CD-ROM | disk | FTP | other *** search
/ Magnum One / Magnum One (Mid-American Digital) (Disc Manufacturing).iso / d13 / pproject.arc / GANTTWIN.CLS < prev    next >
Encoding:
Text File  |  1990-06-07  |  6.9 KB  |  251 lines
  1. /* Maintain a Gantt chart in a Window. The GanttWindow is
  2.    responsible for drawing the project.
  3.  
  4.    GanttWindow descends from the Window class and inherits all
  5.    of its methods and instance variables.
  6. */!!
  7.  
  8. inherit(Window, #GanttWindow, #(project     /* the project */
  9. activities  /* in the project */
  10. barWidth    /* width of a unit */
  11. barHeight   /* based on scrnsize */
  12. activHeight /* bar + dead space */), 2, nil)!!
  13.  
  14. now(GanttWindowClass)!!
  15.  
  16. /* Return the name of this class's MS-Windows window class
  17.   either for registration or new window creation. */
  18. Def wndClass(self)
  19. { ^"GanttWindow"  }!!
  20.  
  21. /* Create a new window class Struct.
  22.    Change the cursor to a cross.  */
  23. Def newWClass(self, lpCl, lpIcon | wc)
  24. { wc := newWClass(self:WindowClass, lpCl, lpIcon);
  25.   putWord(wc, Call LoadCursor(0, IDC_CROSS), 14);
  26.   ^wc;
  27. } !!
  28.  
  29. now(GanttWindow)!!
  30.  
  31. /* See if the user has double clicked on a bar.
  32.    If so, bring up a dialog for editing. */
  33. Def  WM_LBUTTONDBLCLK(self, wP, lP | idx)
  34. {
  35.   idx:= (y(asPoint(lP)) - barHeight) / activHeight;
  36.   if idx <= size(activities) - 1 
  37.     if editInfo(activities[idx]) == IDOK
  38.       dirty(self);
  39.     endif;
  40.   else
  41.     beep();
  42.   endif;
  43. }!!
  44.  
  45. /* For a Task, draw a critical bar.  Make sure we don't draw
  46.    draw over the titles if the node hasn't been hooked up yet.
  47.    Uses early binding, direct Windows calls for speed. */
  48. Def  drawTask(self, aNode, x, y, hDC | startX, hBrush)
  49. {
  50.    startX := max(GW_STARTX, x - asInt(getTime(aNode)*barWidth));
  51.    
  52.    hBrush := Call CreateSolidBrush(CritColor);
  53.    Call SelectObject(hDC, hBrush);   
  54.    Call FillRect(hDC, rect(startX:Int, y, x, y+barHeight), hBrush);
  55.    Call Rectangle(hDC, startX, y, x, y+barHeight);
  56.    Call DeleteObject(Call SelectObject(hDC, hBrush));
  57. }!!
  58.  
  59. /* Create the window using a regular window style. */
  60. Def  create(self, par, wName, rect, style)
  61. { 
  62.   ^create(self:Window, par, wName, rect, 
  63.      WS_POPUPWIND);
  64. }!!
  65.  
  66. /* If we close, be sure to tell the parent. 
  67.    For testing a standalone Gantt chart delete this method. */
  68. Def  close(self)
  69. {
  70.   close(self:Window);
  71.   closeGantt(parent);  /* assumes parent is a ProjWindow */
  72. }!!
  73.  
  74. /* Make sure the parent window knows that the project
  75.    has changed. */
  76. Def  dirty(self)
  77. {
  78.   invalidate(self);
  79.   invalidate(parent);
  80. }!!
  81.  
  82. /* Set up a dummy project, menus and the method table. */
  83. Def  init(self)
  84. {  
  85.   setProject(self, new(Project));
  86.   recalc(project);  
  87.   setMenus(self);
  88.   setResolution(self);
  89. }!!
  90.  
  91. /* Set the resolution for the size of bars, spacing etc.
  92.    For CGA, bars should be smaller. */
  93. Def  setResolution(self | hDC, ts)
  94. {
  95.   hDC := getContext(self);
  96.   ts := textSize(self, hDC);
  97.   releaseContext(self, hDC);
  98.   barHeight := y(ts);
  99.   activHeight := asInt(1.25 * y(ts));
  100. }!!
  101.  
  102. /* Handle menu commands. */
  103. Def  command(self, wp, lp)
  104. {
  105.   select
  106.     case wp == PW_HELP
  107.       help(self);
  108.     endCase
  109.     case wp == PW_VIEW_GANTT  /* open or close, same key */
  110.       close(self);
  111.     endCase
  112.     case wp == PW_FILE_PRINT_GRAPH
  113.       printWindow(self, 1);
  114.     endCase
  115.     case wp == PW_CLIP
  116.       clipWindow(self, 1);
  117.     endCase
  118.   endSelect;
  119. }!!
  120.  
  121. /* Load menu resources. */
  122. Def  setMenus(self)
  123. {
  124.   loadMenu(self, "GWMenus");
  125.   setMenu(self, hMenu);
  126. }
  127. !!
  128.  
  129. /* Display help information from resource file. */
  130. Def  help(self | dlg)
  131. {
  132.   dlg := new(Dialog);
  133.   checkRunModal(dlg, GW_HELP_BOX, self);
  134. }!!
  135.  
  136. /* Draw a Milestone diamond in the window. */
  137. Def  drawMilestone(self, aNode, x, y, hDC)
  138. {
  139.     Call SelectObject(hDC, stock(WHITE_BRUSH));
  140.     draw(new(WinPolygon,
  141.       tuple(
  142.         point(x, y),                 /* top */
  143.         point(x - GW_DMWIDTH, 
  144.               y + barHeight/2),      /* left */
  145.         point(x, y + barHeight),     /* bottom */
  146.         point(x + GW_DMWIDTH,
  147.               y + barHeight/2)       /* right */
  148.       )), hDC);
  149. }!!
  150.  
  151. /* Draw a slack bar in the window. 
  152.    Uses direct Windows call for speed. */
  153. Def  drawSlackBar(self, aNode, x, y, hDC | hBrush)
  154. {
  155.    if CritColor == BLACK then
  156.      Call FrameRect(hDC, rect(x:Int, y, 
  157.                 x + asInt(getSlack(aNode)*barWidth),
  158.                 y + barHeight), stock(BLACK_BRUSH));
  159.    else                
  160.      Call FillRect(hDC, rect(x:Int, y, 
  161.                 x + asInt(getSlack(aNode)*barWidth),
  162.                 y + barHeight), stock(GRAY_BRUSH));
  163.    endif;   
  164. }!!
  165.  
  166. /* Draw text info in the window. */
  167. Def  drawTextInfo(self, aNode, x, y, hDC | str)
  168. {
  169.       if critical(aNode)
  170.         Call SetTextColor(hDC, CritColor);
  171.         str := "*" + getName(aNode);
  172.       else
  173.         Call SetTextColor(hDC, SlackColor);
  174.         str := " " + getName(aNode);
  175.       endif;
  176.       Call TextOut(hDC, x, y, str, size(str));  
  177. }!!
  178.  
  179. /* Set the bar width so that the chart fits in the window. 
  180.    Adjust in case it's very large or very small. */
  181. Def  setBarWidth(self, time)
  182. {
  183.   barWidth := asInt((right(clientRect(self)) - GW_STARTX) / 
  184.                 (time + 1));
  185.   barWidth := min(75, max(2, barWidth));
  186. }!!
  187.  
  188. /* Set the project. */
  189. Def  setProject(self, aProject)
  190. {
  191.   project := aProject;
  192.   recalc(project);
  193. }!!
  194.  
  195. /* Draw the axis for the window. 
  196.    Uses direct Windows calls for speed. */
  197. Def  drawAxis(self, hDC | endX, endY, str)
  198. {
  199.     endX := GW_STARTX + barWidth * 
  200.                (max(2,asInt(getTime(project)+getSlack(project)))) ;  
  201.     endY := activHeight * (size(nodes(project))+1); 
  202.        
  203.     /* draw a rectangle for x and y axis */ 
  204.     
  205.     Call Rectangle(hDC, GW_STARTX, GW_STARTY, endX, endY+1);
  206.         
  207.     /* draw notches on the x axis */    
  208.     do(overBy(GW_STARTX, endX, barWidth),
  209.       {using(i) 
  210.         Call MoveTo(hDC, i, GW_STARTY);           /* top */
  211.         Call LineTo(hDC, i, GW_STARTY + GW_NOTCH);
  212.         Call MoveTo(hDC, i,endY);                 /* bot */
  213.         Call LineTo(hDC, i, endY - GW_NOTCH);
  214.     });
  215.     str := asString(getEarlyStart(project));    
  216.     Call TextOut(hDC, GW_STARTX, endY + 10, str, size(str));  
  217. }!!
  218.  
  219. /* Respond to MS-Windows messages to paint the window. 
  220.    Show the project as a Gantt chart. 
  221.    Draw the axis, then for each node draw the graphics. */
  222. Def  paint(self, hDC | y, t)
  223. {
  224.   setBarWidth(self, asInt(getTime(project)+getSlack(project)));
  225.   activities := sortedActivities(project);
  226.   
  227.   drawAxis(self, hDC);
  228.   y := barHeight;         /* starting positions for bars */
  229.   
  230.   do(activities,
  231.     {using(aNode) 
  232.    
  233.      drawTextInfo(self, aNode, 10, y, hDC);
  234.      
  235.       /* make a temp to avoid calculating starting position */
  236.       t := max(GW_STARTX, GW_STARTX + barWidth *
  237.             asInt(getEarlyStart(aNode)-getEarlyStart(project)+getTime(aNode)));
  238.       
  239.       /* draw a slack bar if necessary. */  
  240.       if getSlack(aNode) > 0  
  241.         drawSlackBar(self, aNode, t, y, hDC)
  242.       endif;
  243.  
  244.       draw(aNode, self, t, y, hDC);  /* node knows how */
  245.  
  246.       y := y + activHeight;     /* move down for next bar */
  247.   });
  248. }!!
  249.  
  250.  
  251.